Kabellose Temperaturmessung für die Loxone Haussteuerung

// 16.05.2026 Jens Dietrich Loxone Sender von Temperaturdaten
// Pin 15 LED ist low active
// D1 als analog Input mit 2,7M + 2,7M um Spannung der Batterie zu messen
// Eine Sendung benötigt etwa 245ms Zeit
// Neuer fester WLAN-Kanal 5

#include <WiFi.h>
#include <esp_now.h>
#include <esp_sleep.h>
#include <OneWire.h>
#include <DallasTemperature.h>

#define SLEEP_TIME 60                              // Sekunden 300 = 5 Minuten
#define LED_PIN    15
#define DEVICE_ID   1                              // Gerätenummer
#define ONE_WIRE_BUS 1                             // Am XIAO mit Pin D1 verwendet

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
DeviceAddress tempDeviceAddress;

// MAC-Adresse vom Empfänger M5 CoreInk
uint8_t receiverMAC[] = {0x64,0xB7,0x08,0xB8,0xDF,0xFC};

typedef struct {                                   // Datenstruktur (11 Byte)
  uint8_t device;
  uint32_t counter;
  float temperature;
  uint16_t battery;
} SensorData;

SensorData data;

RTC_DATA_ATTR uint32_t bootCount = 0;

void onSent(const wifi_tx_info_t *tx_info, esp_now_send_status_t status)
{
  Serial.print("Sendestatus: ");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "OK" : "Fail");
}

void setup() {

  pinMode(LED_PIN , OUTPUT);
  digitalWrite(LED_PIN, LOW);                      // LED ein

  pinMode(A0, INPUT);                              // A0 ist ADC-Input

  Serial.begin(115200);

  data.device = DEVICE_ID;                         // Device-ID

  // 1-Wire-Bus für die Temperaturmessung
  sensors.begin();

  sensors.requestTemperatures();

  // Temperatur auf 0.5 Grad runden
  data.temperature =
      round(sensors.getTempCByIndex(0) * 2.0) / 2.0;

  // Counter im nichtflüchtigen Speicher
  bootCount++;
  data.counter = bootCount;

  WiFi.mode(WIFI_STA);
  WiFi.disconnect();

  if (esp_now_init() != ESP_OK) {
    Serial.println("ESP-NOW Init Fehler");
    return;
  }

  // Batteriespannung ermitteln
  uint32_t Vbatt = 0;

  for (int i = 0; i < 16; i++) {
    Vbatt += analogReadMilliVolts(A0);             // 16x lesen
  }

  // Berechnen und kompensieren
  Vbatt = float(2 * Vbatt / 16);

  data.battery = Vbatt;

  esp_now_register_send_cb(onSent);

  esp_now_peer_info_t peerInfo = {};

  memcpy(peerInfo.peer_addr, receiverMAC, 6);

  peerInfo.channel = 5;                            // Fester WLAN-Kanal 5
  peerInfo.encrypt = false;

  esp_now_add_peer(&peerInfo);

  // Versenden
  esp_now_send(receiverMAC,
               (uint8_t *)&data,
               sizeof(data));

  digitalWrite(LED_PIN, HIGH);                     // LED vor Sleep aus

  esp_deep_sleep(SLEEP_TIME * 1000000ULL);
}

void loop() {
}